#! /bin/csh -f
# set echo

set FLAGS = (-landscape -ppm -xsize=2048 -llx=0.5 -lly=0.5)
set FILES
set PPM = pstopnm
set GIF = ppmtogif
set FLIP = "pnmflip -rotate180"
set WD = `pwd`
set OWD = $WD
set WC = /bin/wc
set LS = /bin/ls
set PSPLOT = $WSOROOT/bin/_$MACHINE/psplot

if ($#argv > 0) then
    while ($#argv > 0)
	if ($1 == "-o") then
	    shift
	    set OWD = $1
	elseif ($1 =~ -*) then
		set FLAGS = ($FLAGS $1)
	else
		if ($1 =~ /*) then
			set FILES = ($FILES $1)
		else
			set FILES = ($FILES $WD/$1)
		endif
	endif
	shift
    end
else
	cat >/tmp/$0.p
	set FILES = /tmp/$0.p
endif

cd /tmp
foreach FILE ($FILES)
    set fname = `basename $FILE ".p"`
    rm -f "$fname"[0-9][0-9]*.ppm 
    $PSPLOT $FILE > $fname.ps
    $PPM $fname.ps $FLAGS
    set plist = ( "$fname"[0-9][0-9]*.ppm )
    if ($#plist > 1) then
        foreach page ( $plist )
	    $FLIP <$page | $GIF >$OWD/$page.gif
        end
    else
        $FLIP <"$fname"001.ppm | $GIF >$OWD/$fname.gif
    endif
    rm -f $fname.ps $fname*.ppm
end